init

share/aclocal/pkg.m4

@@ -0,0 +1,345 @@
+# pkg.m4 - Macros to locate and use pkg-config.   -*- Autoconf -*-
+# serial 12 (pkg-config-0.29.2)
+
+dnl Copyright © 2004 Scott James Remnant <scott@netsplit.com>.
+dnl Copyright © 2012-2015 Dan Nicholson <dbn.lists@gmail.com>
+dnl
+dnl This program is free software; you can redistribute it and/or modify
+dnl it under the terms of the GNU General Public License as published by
+dnl the Free Software Foundation; either version 2 of the License, or
+dnl (at your option) any later version.
+dnl
+dnl This program is distributed in the hope that it will be useful, but
+dnl WITHOUT ANY WARRANTY; without even the implied warranty of
+dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+dnl General Public License for more details.
+dnl
+dnl You should have received a copy of the GNU General Public License
+dnl along with this program; if not, write to the Free Software
+dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
+dnl 02111-1307, USA.
+dnl
+dnl As a special exception to the GNU General Public License, if you
+dnl distribute this file as part of a program that contains a
+dnl configuration script generated by Autoconf, you may include it under
+dnl the same distribution terms that you use for the rest of that
+dnl program.
+
+dnl PKG_PREREQ(MIN-VERSION)
+dnl -----------------------
+dnl Since: 0.29
+dnl
+dnl Verify that the version of the pkg-config macros are at least
+dnl MIN-VERSION. Unlike PKG_PROG_PKG_CONFIG, which checks the user's
+dnl installed version of pkg-config, this checks the developer's version
+dnl of pkg.m4 when generating configure.
+dnl
+dnl To ensure that this macro is defined, also add:
+dnl m4_ifndef([PKG_PREREQ],
+dnl     [m4_fatal([must install pkg-config 0.29 or later before running autoconf/autogen])])
+dnl
+dnl See the "Since" comment for each macro you use to see what version
+dnl of the macros you require.
+m4_defun([PKG_PREREQ],
+[m4_define([PKG_MACROS_VERSION], [0.29.2])
+m4_if(m4_version_compare(PKG_MACROS_VERSION, [$1]), -1,
+    [m4_fatal([pkg.m4 version $1 or higher is required but ]PKG_MACROS_VERSION[ found])])
+])dnl PKG_PREREQ
+
+dnl PKG_PROG_PKG_CONFIG([MIN-VERSION])
+dnl ----------------------------------
+dnl Since: 0.16
+dnl
+dnl Search for the pkg-config tool and set the PKG_CONFIG variable to
+dnl first found in the path. Checks that the version of pkg-config found
+dnl is at least MIN-VERSION. If MIN-VERSION is not specified, 0.9.0 is
+dnl used since that's the first version where most current features of
+dnl pkg-config existed.
+AC_DEFUN([PKG_PROG_PKG_CONFIG],
+[m4_pattern_forbid([^_?PKG_[A-Z_]+$])
+m4_pattern_allow([^PKG_CONFIG(_(PATH|LIBDIR|SYSROOT_DIR|ALLOW_SYSTEM_(CFLAGS|LIBS)))?$])
+m4_pattern_allow([^PKG_CONFIG_(DISABLE_UNINSTALLED|TOP_BUILD_DIR|DEBUG_SPEW)$])
+AC_ARG_VAR([PKG_CONFIG], [path to pkg-config utility])
+AC_ARG_VAR([PKG_CONFIG_PATH], [directories to add to pkg-config's search path])
+AC_ARG_VAR([PKG_CONFIG_LIBDIR], [path overriding pkg-config's built-in search path])
+
+if test "x$ac_cv_env_PKG_CONFIG_set" != "xset"; then
+	AC_PATH_TOOL([PKG_CONFIG], [pkg-config])
+fi
+if test -n "$PKG_CONFIG"; then
+	_pkg_min_version=m4_default([$1], [0.9.0])
+	AC_MSG_CHECKING([pkg-config is at least version $_pkg_min_version])
+	if $PKG_CONFIG --atleast-pkgconfig-version $_pkg_min_version; then
+		AC_MSG_RESULT([yes])
+	else
+		AC_MSG_RESULT([no])
+		PKG_CONFIG=""
+	fi
+fi[]dnl
+])dnl PKG_PROG_PKG_CONFIG
+
+dnl PKG_CHECK_EXISTS(MODULES, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
+dnl -------------------------------------------------------------------
+dnl Since: 0.18
+dnl
+dnl Check to see whether a particular set of modules exists. Similar to
+dnl PKG_CHECK_MODULES(), but does not set variables or print errors.
+dnl
+dnl Please remember that m4 expands AC_REQUIRE([PKG_PROG_PKG_CONFIG])
+dnl only at the first occurrence in configure.ac, so if the first place
+dnl it's called might be skipped (such as if it is within an "if", you
+dnl have to call PKG_CHECK_EXISTS manually
+AC_DEFUN([PKG_CHECK_EXISTS],
+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
+if test -n "$PKG_CONFIG" && \
+    AC_RUN_LOG([$PKG_CONFIG --exists --print-errors "$1"]); then
+  m4_default([$2], [:])
+m4_ifvaln([$3], [else
+  $3])dnl
+fi])
+
+dnl _PKG_CONFIG([VARIABLE], [COMMAND], [MODULES])
+dnl ---------------------------------------------
+dnl Internal wrapper calling pkg-config via PKG_CONFIG and setting
+dnl pkg_failed based on the result.
+m4_define([_PKG_CONFIG],
+[if test -n "$$1"; then
+    pkg_cv_[]$1="$$1"
+ elif test -n "$PKG_CONFIG"; then
+    PKG_CHECK_EXISTS([$3],
+                     [pkg_cv_[]$1=`$PKG_CONFIG --[]$2 "$3" 2>/dev/null`
+		      test "x$?" != "x0" && pkg_failed=yes ],
+		     [pkg_failed=yes])
+ else
+    pkg_failed=untried
+fi[]dnl
+])dnl _PKG_CONFIG
+
+dnl _PKG_SHORT_ERRORS_SUPPORTED
+dnl ---------------------------
+dnl Internal check to see if pkg-config supports short errors.
+AC_DEFUN([_PKG_SHORT_ERRORS_SUPPORTED],
+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])
+if $PKG_CONFIG --atleast-pkgconfig-version 0.20; then
+        _pkg_short_errors_supported=yes
+else
+        _pkg_short_errors_supported=no
+fi[]dnl
+])dnl _PKG_SHORT_ERRORS_SUPPORTED
+
+
+dnl PKG_CHECK_MODULES(VARIABLE-PREFIX, MODULES, [ACTION-IF-FOUND],
+dnl   [ACTION-IF-NOT-FOUND])
+dnl --------------------------------------------------------------
+dnl Since: 0.4.0
+dnl
+dnl Note that if there is a possibility the first call to
+dnl PKG_CHECK_MODULES might not happen, you should be sure to include an
+dnl explicit call to PKG_PROG_PKG_CONFIG in your configure.ac
+AC_DEFUN([PKG_CHECK_MODULES],
+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
+AC_ARG_VAR([$1][_CFLAGS], [C compiler flags for $1, overriding pkg-config])dnl
+AC_ARG_VAR([$1][_LIBS], [linker flags for $1, overriding pkg-config])dnl
+
+pkg_failed=no
+AC_MSG_CHECKING([for $2])
+
+_PKG_CONFIG([$1][_CFLAGS], [cflags], [$2])
+_PKG_CONFIG([$1][_LIBS], [libs], [$2])
+_PKG_CONFIG([$1][_VERSION], [modversion], [$2])
+
+m4_define([_PKG_TEXT], [Alternatively, you may set the environment variables $1[]_CFLAGS
+and $1[]_LIBS to avoid the need to call pkg-config.
+See the pkg-config man page for more details.])
+
+if test $pkg_failed = yes; then
+        AC_MSG_RESULT([no])
+        _PKG_SHORT_ERRORS_SUPPORTED
+        if test $_pkg_short_errors_supported = yes; then
+                $1[]_PKG_ERRORS=`$PKG_CONFIG --short-errors --print-errors --cflags --libs "$2" 2>&1`
+        else
+                $1[]_PKG_ERRORS=`$PKG_CONFIG --print-errors --cflags --libs "$2" 2>&1`
+        fi
+        # Put the nasty error message in config.log where it belongs
+        echo "$$1[]_PKG_ERRORS" >&AS_MESSAGE_LOG_FD
+
+        m4_default([$4], [AC_MSG_ERROR(
+[Package requirements ($2) were not met:
+
+$$1_PKG_ERRORS
+
+Consider adjusting the PKG_CONFIG_PATH environment variable if you
+installed software in a non-standard prefix.
+
+_PKG_TEXT])[]dnl
+        ])
+elif test $pkg_failed = untried; then
+        AC_MSG_RESULT([no])
+        m4_default([$4], [AC_MSG_FAILURE(
+[The pkg-config script could not be found or is too old.  Make sure it
+is in your PATH or set the PKG_CONFIG environment variable to the full
+path to pkg-config.
+
+_PKG_TEXT
+
+To get pkg-config, see <http://pkg-config.freedesktop.org/>.])[]dnl
+        ])
+else
+        $1[]_CFLAGS=$pkg_cv_[]$1[]_CFLAGS
+        $1[]_LIBS=$pkg_cv_[]$1[]_LIBS
+        $1[]_VERSION=$pkg_cv_[]$1[]_VERSION
+        AC_MSG_RESULT([yes])
+        $3
+fi[]dnl
+])dnl PKG_CHECK_MODULES
+
+
+dnl PKG_CHECK_MODULES_STATIC(VARIABLE-PREFIX, MODULES, [ACTION-IF-FOUND],
+dnl   [ACTION-IF-NOT-FOUND])
+dnl ---------------------------------------------------------------------
+dnl Since: 0.29
+dnl
+dnl Checks for existence of MODULES and gathers its build flags with
+dnl static libraries enabled. Sets VARIABLE-PREFIX_CFLAGS from --cflags
+dnl and VARIABLE-PREFIX_LIBS from --libs.
+dnl
+dnl Note that if there is a possibility the first call to
+dnl PKG_CHECK_MODULES_STATIC might not happen, you should be sure to
+dnl include an explicit call to PKG_PROG_PKG_CONFIG in your
+dnl configure.ac.
+AC_DEFUN([PKG_CHECK_MODULES_STATIC],
+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
+_save_PKG_CONFIG=$PKG_CONFIG
+PKG_CONFIG="$PKG_CONFIG --static"
+PKG_CHECK_MODULES($@)
+PKG_CONFIG=$_save_PKG_CONFIG[]dnl
+])dnl PKG_CHECK_MODULES_STATIC
+
+
+dnl PKG_INSTALLDIR([DIRECTORY])
+dnl -------------------------
+dnl Since: 0.27
+dnl
+dnl Substitutes the variable pkgconfigdir as the location where a module
+dnl should install pkg-config .pc files. By default the directory is
+dnl $libdir/pkgconfig, but the default can be changed by passing
+dnl DIRECTORY. The user can override through the --with-pkgconfigdir
+dnl parameter.
+AC_DEFUN([PKG_INSTALLDIR],
+[m4_pushdef([pkg_default], [m4_default([$1], ['${libdir}/pkgconfig'])])
+m4_pushdef([pkg_description],
+    [pkg-config installation directory @<:@]pkg_default[@:>@])
+AC_ARG_WITH([pkgconfigdir],
+    [AS_HELP_STRING([--with-pkgconfigdir], pkg_description)],,
+    [with_pkgconfigdir=]pkg_default)
+AC_SUBST([pkgconfigdir], [$with_pkgconfigdir])
+m4_popdef([pkg_default])
+m4_popdef([pkg_description])
+])dnl PKG_INSTALLDIR
+
+
+dnl PKG_NOARCH_INSTALLDIR([DIRECTORY])
+dnl --------------------------------
+dnl Since: 0.27
+dnl
+dnl Substitutes the variable noarch_pkgconfigdir as the location where a
+dnl module should install arch-independent pkg-config .pc files. By
+dnl default the directory is $datadir/pkgconfig, but the default can be
+dnl changed by passing DIRECTORY. The user can override through the
+dnl --with-noarch-pkgconfigdir parameter.
+AC_DEFUN([PKG_NOARCH_INSTALLDIR],
+[m4_pushdef([pkg_default], [m4_default([$1], ['${datadir}/pkgconfig'])])
+m4_pushdef([pkg_description],
+    [pkg-config arch-independent installation directory @<:@]pkg_default[@:>@])
+AC_ARG_WITH([noarch-pkgconfigdir],
+    [AS_HELP_STRING([--with-noarch-pkgconfigdir], pkg_description)],,
+    [with_noarch_pkgconfigdir=]pkg_default)
+AC_SUBST([noarch_pkgconfigdir], [$with_noarch_pkgconfigdir])
+m4_popdef([pkg_default])
+m4_popdef([pkg_description])
+])dnl PKG_NOARCH_INSTALLDIR
+
+
+dnl PKG_CHECK_VAR(VARIABLE, MODULE, CONFIG-VARIABLE,
+dnl [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
+dnl -------------------------------------------
+dnl Since: 0.28
+dnl
+dnl Retrieves the value of the pkg-config variable for the given module.
+AC_DEFUN([PKG_CHECK_VAR],
+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
+AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
+
+_PKG_CONFIG([$1], [variable="][$3]["], [$2])
+AS_VAR_COPY([$1], [pkg_cv_][$1])
+
+AS_VAR_IF([$1], [""], [$5], [$4])dnl
+])dnl PKG_CHECK_VAR
+
+dnl PKG_WITH_MODULES(VARIABLE-PREFIX, MODULES,
+dnl   [ACTION-IF-FOUND],[ACTION-IF-NOT-FOUND],
+dnl   [DESCRIPTION], [DEFAULT])
+dnl ------------------------------------------
+dnl
+dnl Prepare a "--with-" configure option using the lowercase
+dnl [VARIABLE-PREFIX] name, merging the behaviour of AC_ARG_WITH and
+dnl PKG_CHECK_MODULES in a single macro.
+AC_DEFUN([PKG_WITH_MODULES],
+[
+m4_pushdef([with_arg], m4_tolower([$1]))
+
+m4_pushdef([description],
+           [m4_default([$5], [build with ]with_arg[ support])])
+
+m4_pushdef([def_arg], [m4_default([$6], [auto])])
+m4_pushdef([def_action_if_found], [AS_TR_SH([with_]with_arg)=yes])
+m4_pushdef([def_action_if_not_found], [AS_TR_SH([with_]with_arg)=no])
+
+m4_case(def_arg,
+            [yes],[m4_pushdef([with_without], [--without-]with_arg)],
+            [m4_pushdef([with_without],[--with-]with_arg)])
+
+AC_ARG_WITH(with_arg,
+     AS_HELP_STRING(with_without, description[ @<:@default=]def_arg[@:>@]),,
+    [AS_TR_SH([with_]with_arg)=def_arg])
+
+AS_CASE([$AS_TR_SH([with_]with_arg)],
+            [yes],[PKG_CHECK_MODULES([$1],[$2],$3,$4)],
+            [auto],[PKG_CHECK_MODULES([$1],[$2],
+                                        [m4_n([def_action_if_found]) $3],
+                                        [m4_n([def_action_if_not_found]) $4])])
+
+m4_popdef([with_arg])
+m4_popdef([description])
+m4_popdef([def_arg])
+
+])dnl PKG_WITH_MODULES
+
+dnl PKG_HAVE_WITH_MODULES(VARIABLE-PREFIX, MODULES,
+dnl   [DESCRIPTION], [DEFAULT])
+dnl -----------------------------------------------
+dnl
+dnl Convenience macro to trigger AM_CONDITIONAL after PKG_WITH_MODULES
+dnl check._[VARIABLE-PREFIX] is exported as make variable.
+AC_DEFUN([PKG_HAVE_WITH_MODULES],
+[
+PKG_WITH_MODULES([$1],[$2],,,[$3],[$4])
+
+AM_CONDITIONAL([HAVE_][$1],
+               [test "$AS_TR_SH([with_]m4_tolower([$1]))" = "yes"])
+])dnl PKG_HAVE_WITH_MODULES
+
+dnl PKG_HAVE_DEFINE_WITH_MODULES(VARIABLE-PREFIX, MODULES,
+dnl   [DESCRIPTION], [DEFAULT])
+dnl ------------------------------------------------------
+dnl
+dnl Convenience macro to run AM_CONDITIONAL and AC_DEFINE after
+dnl PKG_WITH_MODULES check. HAVE_[VARIABLE-PREFIX] is exported as make
+dnl and preprocessor variable.
+AC_DEFUN([PKG_HAVE_DEFINE_WITH_MODULES],
+[
+PKG_HAVE_WITH_MODULES([$1],[$2],[$3],[$4])
+
+AS_IF([test "$AS_TR_SH([with_]m4_tolower([$1]))" = "yes"],
+        [AC_DEFINE([HAVE_][$1], 1, [Enable ]m4_tolower([$1])[ support])])
+])dnl PKG_HAVE_DEFINE_WITH_MODULES

share/doc/pkgconf/AUTHORS

@@ -0,0 +1,41 @@
+A. Wilcox <AWilcox@Wilcox-Tech.com>
+Alexander Tsoy <alexander@tsoy.me>
+Alexpux <alexey.pawlow@gmail.com>
+Alon Bar-Lev <alon.barlev@gmail.com>
+Alyx <alyx@malkier.net>
+Ariadne Conill <ariadne@dereferenced.org>
+Baptiste Daroussin <bapt@FreeBSD.org>
+Baptiste Daroussin <bapt@gandi.net>
+Bryan Drewery <bryan@shatow.net>
+Dag-Erling Smørgrav <des@des.no>
+Dan Kegel <dank@kegel.com>
+Dan Kegel <dank@oblong.com>
+Dan Nicholson <dbn.lists@gmail.com>
+David Michael <fedora.dm0@gmail.com>
+Emil Renner Berthing <esmil@mailme.dk>
+Fabian Groffen <grobian@gentoo.org>
+Graham Ollis <plicease@cpan.org>
+Gregor Richards <Richards@codu.org>
+Ignacio Casal Quinteiro <qignacio@amazon.com>
+Igor Gnatenko <ignatenko@redhat.com>
+Issam Maghni <concatime@users.noreply.github.com>
+JD Horelick <jdhore1@gmail.com>
+Jason Dusek <jason.dusek@gmail.com>
+Javier Viguera <javier.viguera@digi.com>
+Jean-Sébastien Pédron <dumbbell@FreeBSD.org>
+John Hein <jhgit@users.github.com>
+Jussi Pakkanen <jpakkane@gmail.com>
+Leorize <alaviss@users.noreply.github.com>
+Luca Barbato <lu_zero@gentoo.org>
+Marcin Wojdyr <wojdyr@gmail.com>
+Maxin B. John <maxinbjohn@users.noreply.github.com>
+Michał Górny <mgorny@gentoo.org>
+Mike Frysinger <vapier@gentoo.org>
+Seungha Yang <seungha.yang@navercorp.com>
+TingPing <tingping@tingping.se>
+Tobias Kortkamp <t6@users.noreply.github.com>
+Tony Theodore <tonyt@logyst.com>
+Volker Braun <vbraun.name@gmail.com>
+Yu Kobayashi <yukoba@accelart.jp>
+orbea <orbea@fredslev.dk>
+✈ Graham ✈ <plicease@cpan.org>

share/doc/pkgconf/README.md

@@ -0,0 +1,149 @@
+# pkgconf [![test](https://github.com/pkgconf/pkgconf/actions/workflows/test.yml/badge.svg)](https://github.com/pkgconf/pkgconf/actions/workflows/test.yml)
+
+`pkgconf` is a program which helps to configure compiler and linker flags for
+development libraries.  It is similar to pkg-config from freedesktop.org.
+
+`libpkgconf` is a library which provides access to most of `pkgconf`'s functionality, 
+to allow other tooling such as compilers and IDEs to discover and use libraries 
+configured by pkgconf.
+
+## using `pkgconf` with autotools
+
+Implementations of pkg-config, such as pkgconf, are typically used with the
+PKG_CHECK_MODULES autoconf macro.  As far as we know, pkgconf is
+compatible with all known variations of this macro. pkgconf detects at
+runtime whether or not it was started as 'pkg-config', and if so, attempts
+to set program options such that its behaviour is similar.
+
+In terms of the autoconf macro, it is possible to specify the PKG_CONFIG
+environment variable, so that you can test pkgconf without overwriting your
+pkg-config binary.  Some other build systems may also respect the PKG_CONFIG
+environment variable.
+
+To set the environment variable on the bourne shell and clones (i.e. bash), you
+can run:
+
+    $ export PKG_CONFIG=/usr/bin/pkgconf
+
+## comparison of `pkgconf` and `pkg-config` dependency resolvers
+
+pkgconf builds an acyclic directed dependency graph.  This allows for the user
+to more conservatively link their binaries -- which may be helpful in some
+environments, such as when prelink(1) is being used.  As a result of building
+a directed dependency graph designed for the specific problem domain provided
+by the user, more accurate dependencies can be determined.
+
+Current release versions of pkg-config, on the other hand, build a database of all
+known pkg-config files on the system before attempting to resolve dependencies, which
+is a considerably slower and less efficient design.  Efforts have been made recently
+to improve this behaviour.
+
+As of the 1.1 series, pkgconf also fully implements support for `Provides` rules,
+while pkg-config does not.  pkg-config only provides the `--print-provides` functionality
+as a stub.  There are other intentional implementation differences in pkgconf's dependency
+resolver versus pkg-config's dependency resolver in terms of completeness and correctness,
+such as, for example, how `Conflicts` rules are processed.
+
+## linker flags optimization
+
+As previously mentioned, pkgconf makes optimizations to the linker flags in both the
+case of static and shared linking in order to avoid overlinking binaries and also
+simplifies the `CFLAGS` and `LIBS` output of the pkgconf tool for improved readability.
+
+This functionality depends on the pkg-config module properly declaring it's dependency
+tree instead of using `Libs` and `Cflags` fields to directly link against other modules
+which have pkg-config metadata files installed.
+
+Doing so is discouraged by the [freedesktop tutorial][fd-tut] anyway.
+
+   [fd-tut]: http://people.freedesktop.org/~dbn/pkg-config-guide.html
+
+## compatibility with pkg-config
+
+I really hate that I have to have this section, I like being a nice person, but we
+unfortunately have to say this because otherwise we get passive-aggressive people who
+try to argue with us about what pkg-config compatibility means.
+
+We do not provide bug-level compatibility with pkg-config.
+
+What that means is, if you feel that there is a legitimate regression versus pkg-config,
+do let us know, but also make sure that the .pc files are valid and follow the rules of
+the [pkg-config tutorial][fd-tut], as most likely fixing them to follow the specified
+rules will solve the problem.
+
+Additionally, **we do not consider pkgconf doing what you tell it to do, in cases for 
+which pkg-config fails to do so, to be a bug**.
+
+If, for example, you use environment variables such as `PKG_CONFIG_SYSTEM_[INCLUDE|LIBRARY]_PATH`
+and then find yourself surprised that `pkgconf` is stripping `-I` and `-L` flags relating
+to those paths, it is not a `pkgconf` problem -- `pkgconf` is doing exactly what you told
+it to do.
+
+We will reject bugs like this, and if someone insists on fixing such a non-bug, this 
+constitutes a violation of our [Code of Conduct](CODE_OF_CONDUCT.md), which may be 
+addressed by banning from this repository.
+
+## debug output
+
+Please use only the stable interfaces to query pkg-config.  Do not screen-scrape the
+output from `--debug`: this is sent to `stderr` for a reason, it is not intended to be
+scraped.  The `--debug` output is **not** a stable interface, and should **never** be
+depended on as a source of information.  If you need a stable interface to query pkg-config
+which is not covered, please get in touch.
+
+## compiling `pkgconf` and `libpkgconf` on UNIX
+
+pkgconf is basically compiled the same way any other autotools-based project is
+compiled:
+
+    $ ./configure
+    $ make
+    $ sudo make install
+
+If you are installing pkgconf into a custom prefix, such as `/opt/pkgconf`, you will
+likely want to define the default system includedir and libdir for your toolchain.
+To do this, use the `--with-system-includedir` and `--with-system-libdir` configure
+flags like so:
+
+    $ ./configure \
+         --prefix=/opt/pkgconf \
+         --with-system-libdir=/lib:/usr/lib \
+         --with-system-includedir=/usr/include
+    $ make
+    $ sudo make install
+
+## compiling `pkgconf` and `libpkgconf` with Meson (usually for Windows)
+
+
+pkgconf is compiled using [Meson](https://mesonbuild.com) on Windows. In theory, you could also use
+Meson to build on UNIX, but this is not recommended at this time as it pkgconf is typically built
+much earlier than Meson.
+
+    $ meson setup build -Dtests=false
+    $ meson compile -C build
+    $ meson install -C build
+
+There are a few defines such as SYSTEM_LIBDIR, PKGCONFIGDIR and SYSTEM_INCLUDEDIR.
+However, on Windows, the default PKGCONFIGDIR value is usually overridden at runtime based
+on path relocation.
+
+## pkg-config symlink
+
+If you want pkgconf to be used when you invoke `pkg-config`, you should install a
+symlink for this.  We do not do this for you, as we believe it is better for vendors
+to make this determination themselves.
+
+    $ ln -sf pkgconf /usr/bin/pkg-config
+
+## release tarballs
+
+Release tarballs are available at <https://distfiles.dereferenced.org/pkgconf/>.
+Please only use the tarballs from distfiles.dereferenced.org.
+
+## contacts
+
+You can report bugs at <https://github.com/pkgconf/pkgconf/issues>.
+
+There is a mailing list at <https://lists.sr.ht/~kaniini/pkgconf>.
+
+You can contact us via IRC at `#pkgconf` at `irc.oftc.net`.